MACRO Requests

[amonseti]

I have a foundation set up for this now .. So if you can make me a keeper list and give me an idea of how you would like them sorted / separted amoungst books / containers (IE how many books , junk toss container, bod books for each ore / leather type , whatever you like)
for exsample more :
Bods that contribute to reward val hammer go into "Smity book A"
Bods that contribute to T5 cloth go into "Tailor Book D"

so give me a list that looks like this
Large 20 excp Val Plate >>into book>> "Smity book A"
Small 15 excp Barbed Bone Chest >>into book>> "Tailor Book D"

Now you dont need to sort it like in my exsample.. what ever way you think is best for sorting thats cool. ill just need to know how many Books or containers we need . and what bods go into what book ( BOD >>into book >> "the bod book").

* Also I will included your name in the credits for assisting with the creation of this Macro*

 

[Kilike]

I have a foundation set up for this now .. So if you can make me a keeper list and give me an idea of how you would like them sorted / separted amoungst books / containers (IE how many books , junk toss container, bod books for each ore / leather type , whatever you like)
for exsample more :
Bods that contribute to reward val hammer go into "Smity book A"
Bods that contribute to T5 cloth go into "Tailor Book D"

so give me a list that looks like this
Large 20 excp Val Plate >>into book>> "Smity book A"
Small 15 excp Barbed Bone Chest >>into book>> "Tailor Book D"

Now you dont need to sort it like in my exsample.. what ever way you think is best for sorting thats cool. ill just need to know how many Books or containers we need . and what bods go into what book ( BOD >>into book >> "the bod book").

* Also I will included your name in the credits for assisting with the creation of this Macro*

When I get home I'll work on getting you this list. Thanks

Sent from my SM-G900P

 

[drinn]

NP got it working

 

[Kryptoknight]

A macro that crafts leather suits then dyes and bags them would be really useful

 

[Thryn]

Speaking of BODs, I could have sworn I knew of a Tailor SBOD filler that was floating around. I think I have an old copy of it that may or may not be compatible with UOF. Anyone have an updated version?

 

[amonseti]

Speaking of BODs, I could have sworn I knew of a Tailor SBOD filler that was floating around. I think I have an old copy of it that may or may not be compatible with UOF. Anyone have an updated version?

ugg i have been putting this off for quite a while as its a data whore .. mabey eventually ill get it done .

 

[Thryn]

I can PM you the foundation that may or may not work on here if that'll help you get started?

 

[eppy]

A macro that crafts leather suits then dyes and bags them would be really useful

I have most of this one somewhere. You need 120 tailor though so you don't fail.

 

[amonseti]

A macro that crafts leather suits then dyes and bags them would be really useful

I have a leather armor sorting macro I made that not only sorts leather parts (Gloves, gorget, chest etc ) but also dyes them with a color based on its propertys (Massive , Invul, Normal excep, etc) .. Ill share this tonight .

 

[amonseti]

A macro that crafts leather suits then dyes and bags them would be really useful

As promised heres the macro
Leather Armor Manager (Requires Leather Dye Tub)

 

[amonseti]

I can PM you the foundation that may or may not work on here if that'll help you get started?

Thx not sure if this will work, needs some fix's as UOF does not allow server requests .

 

[DocOp]

I'd love to know a slayer one. I use steam but recently converted from razor. I enjoy crafting. Even the tediousness of mining is relaxing for me from my bullshit job. Idm mining, I have a item one to redo pick axe. So I'm fine in that regard. But Jesus H almighty Christ, a couple hundred more 'smelt item' clicks and I'm going turn into a super villain. I don't even care to make all the shit by clicking. Just one for activating smelt item would be fucking wonderful. I don't know wtf a gump is besides like pop up shit. So basically if you were to help me you'd have to explain it thoroughly for my dumbass, dumb brain even. Yes, I've seen people post their slayer macros and still haven't a clue what they're talking about. Help or no, thanks in advance.

 

[Wizx13]

Need a magery recall lumberjack macro. Multiple books would be sweet!!

 

[amonseti]

I'd love to know a slayer one. I use steam but recently converted from razor. I enjoy crafting. Even the tediousness of mining is relaxing for me from my bullshit job. Idm mining, I have a item one to redo pick axe. So I'm fine in that regard. But Jesus H almighty Christ, a couple hundred more 'smelt item' clicks and I'm going turn into a super villain. I don't even care to make all the shit by clicking. Just one for activating smelt item would be fucking wonderful. I don't know wtf a gump is besides like pop up shit. So basically if you were to help me you'd have to explain it thoroughly for my dumbass, dumb brain even. Yes, I've seen people post their slayer macros and still haven't a clue what they're talking about. Help or no, thanks in advance.

im a little confused what exsactly would you like the macro to do .. assist with mining or creating slayer weps ?

 

[DocOp]

@amonseti. Sorry. Got a little carried away. I want a slayer macro. But not even necessarily one that sorts and smelts, and basically does everything. I would just like to know how to get a hot key that activates the 'smelt item' Id be so happy with that alone. I've been having trouble figuring it out cause the item, tongs, are losing durability and at a point become destroyed.

 

[amonseti]

@amonseti. Sorry. Got a little carried away. I want a slayer macro. But not even necessarily one that sorts and smelts, and basically does everything. I would just like to know how to get a hot key that activates the 'smelt item' Id be so happy with that alone. I've been having trouble figuring it out cause the item, tongs, are losing durability and at a point become destroyed.

So a macro that just asks you for a target , and then smelts it . ?
Not a problem Ill whip that together when I get home tonight .

 

[DocOp]

Actually, I hope you find this first. But I managed to figure it out. Thank you for paying me mind though, I appreciate it. Now i can smash these fuckers out without wanting to kill someone

 

[amonseti]

Actually, I hope you find this first. But I managed to figure it out. Thank you for paying me mind though, I appreciate it. Now i can smash these fuckers out without wanting to kill someone

kk thx for the heads up.

 

[Gosh]

Speaking of BODs, I could have sworn I knew of a Tailor SBOD filler that was floating around. I think I have an old copy of it that may or may not be compatible with UOF. Anyone have an updated version?

I've found those BOD fillers on another shards forum, you can test and maybe adapt:

Tailor
Instructions:
- Mark "Loop" and play the macro
- "Bulk Source" is the BOB with BODs you want to fill
- "Bulk Destination" is another BOB where filled BODs will be placed
- "Restock" is a container with leathers (normal, spined, horned and barbed), cloth and sewing kits
- "Trash BODs Destination" can be a container or a BOB where the macro will place BODs it cannot fill
- Have a scissors inside your backpack to recycle items
- Keep your character close to a trash barrel and all selected containers

// Author: Kraz
// Description: Tailoring BOD Filler
// v2.1: fixed issue where it could not craft footwear
// v2.0: (1) easier to update, read and edit craft info, (2) search, recycle and combine existing items before crafting, (3) faster crafting due to gump category swap improvements, (4) added resource handler
if not @findobject 'Bulk Source'
  promptalias 'Bulk Source'
endif
if not @findobject 'Bulk Destination'
  promptalias 'Bulk Destination'
endif
if not @findobject 'Restock'
  promptalias 'Restock'
endif
if not @findobject 'Trash BODs Destination'
  promptalias 'Trash BODs Destination'
endif
if not @findobject 'Trash Barrel'
  promptalias 'Trash Barrel'
endif
// Craft info placeholder
if not listexists 'Craft'
  @createlist 'Craft'
  // 0: Category, 1: Button, 2: Graphic, 3: Resource Button, 4: Resource Color
endif
// Search for a BOD to fill
if @findtype 0x2258 0x483 'backpack' and @property 'small' 'found'
  // Reset craft state
  @clearlist 'Craft'
  @unsetalias 'crafting'
  // Define and open new BOD
  @setalias 'bod' 'found'
  useobject! 'bod'
  waitforgump 0x5afbd742 15000
  // Combine items
  if not targetexists 'server'
    replygump 0x5afbd742 2
    waitforgump 0x5afbd742 15000
    waitfortarget 5000
  endif
  // Check for tools
  if @findtype 0xf9d 0 'backpack'
    pause 1500
    @setalias 'tool' 'found'
    useobject! 'tool'
    waitforgump 0x38920abd 15000
    // Craft
    while targetexists 'server'
      // Define BOD material type
      @setalias 'cloth' 'bod'
      if @ingump 0x5afbd742 'leather' or @ingump 0x5afbd742 'studded'
        @unsetalias 'cloth'
      elseif @ingump 0x5afbd742 'boots' and not @ingump 0x5afbd742 'fur boots'
        @unsetalias 'cloth'
      elseif @ingump 0x5afbd742 'shoes' or @ingump 0x5afbd742 'sandals'
        @unsetalias 'cloth'
      endif
      // Craft requirements
      if @findalias 'cloth'
        // Check for cut cloths
        if @counttype 0x1766 'any' 'backpack' < 50 and @counttype 0x1767 'any' 'backpack' < 50
          if @movetype 0x1766 'Restock' 'backpack' 0 0 0 'any' 100 or @movetype 0x1767 'Restock' 'backpack' 0 0 0 'any' 100
            pause 1500
          else
            sysmsg 'Out of cloths!' 25
            @canceltarget
            stop
          endif
        endif
        if not @findalias 'crafting'
          // Hats
          if @ingump 0x5afbd742 'skullcap'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 2
            @pushlist 'Craft' 0x1544
          elseif @ingump 0x5afbd742 'bandana'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 9
            @pushlist 'Craft' 0x1540
          elseif @ingump 0x5afbd742 'floppy hat'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 16
            @pushlist 'Craft' 0x1713
          elseif @ingump 0x5afbd742 'cap'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 23
            @pushlist 'Craft' 0x1715
          elseif @ingump 0x5afbd742 'wide-brim hat'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 30
            @pushlist 'Craft' 0x1714
          elseif @ingump 0x5afbd742 'tall straw hat'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 44
            @pushlist 'Craft' 0x1716
          elseif @ingump 0x5afbd742 'straw hat'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 37
            @pushlist 'Craft' 0x1717
          elseif @ingump 0x5afbd742 "wizard's hat"
            @pushlist 'Craft' 1
            @pushlist 'Craft' 51
            @pushlist 'Craft' 0x1718
          elseif @ingump 0x5afbd742 'bonnet'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 58
            @pushlist 'Craft' 0x1719
          elseif @ingump 0x5afbd742 'feathered hat'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 65
            @pushlist 'Craft' 0x171a
          elseif @ingump 0x5afbd742 'tricorne hat'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 72
            @pushlist 'Craft' 0x171b
          elseif @ingump 0x5afbd742 'jester hat'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 79
            @pushlist 'Craft' 0x171c
          elseif @ingump 0x5afbd742 'flower garland'
            @pushlist 'Craft' 1
            @pushlist 'Craft' 86
            @pushlist 'Craft' 0x2306
            // Shirts
          elseif @ingump 0x5afbd742 'doublet'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 2
            @pushlist 'Craft' 0x1f7b
          elseif @ingump 0x5afbd742 'fancy shirt'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 16
            @pushlist 'Craft' 0x1efd
          elseif @ingump 0x5afbd742 'formal shirt'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 86
            @pushlist 'Craft' 0x2310
          elseif @ingump 0x5afbd742 'shirt'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 9
            @pushlist 'Craft' 0x1517
          elseif @ingump 0x5afbd742 'tunic'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 23
            @pushlist 'Craft' 0x1fa1
          elseif @ingump 0x5afbd742 'surcoat'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 30
            @pushlist 'Craft' 0x1ffd
          elseif @ingump 0x5afbd742 'plain dress'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 37
            @pushlist 'Craft' 0x1f01
          elseif @ingump 0x5afbd742 'fancy dress'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 44
            @pushlist 'Craft' 0x1f00
          elseif @ingump 0x5afbd742 'cloak'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 51
            @pushlist 'Craft' 0x1515
          elseif @ingump 0x5afbd742 'robe'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 58
            @pushlist 'Craft' 0x1f03
          elseif @ingump 0x5afbd742 'jester suit'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 65
            @pushlist 'Craft' 0x1f9f
          elseif @ingump 0x5afbd742 'fur cape'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 72
            @pushlist 'Craft' 0x230a
          elseif @ingump 0x5afbd742 'gilded dress'
            @pushlist 'Craft' 8
            @pushlist 'Craft' 79
            @pushlist 'Craft' 0x230e
            // Pants
          elseif @ingump 0x5afbd742 'short pants'
            @pushlist 'Craft' 15
            @pushlist 'Craft' 2
            @pushlist 'Craft' 0x152e
          elseif @ingump 0x5afbd742 'long pants'
            @pushlist 'Craft' 15
            @pushlist 'Craft' 9
            @pushlist 'Craft' 0x1539
          elseif @ingump 0x5afbd742 'kilt'
            @pushlist 'Craft' 15
            @pushlist 'Craft' 16
            @pushlist 'Craft' 0x1537
          elseif @ingump 0x5afbd742 'skirt'
            @pushlist 'Craft' 15
            @pushlist 'Craft' 23
            @pushlist 'Craft' 0x1516
            // Miscellaneous
          elseif @ingump 0x5afbd742 'body sash'
            @pushlist 'Craft' 22
            @pushlist 'Craft' 2
            @pushlist 'Craft' 0x1541
          elseif @ingump 0x5afbd742 'half apron'
            @pushlist 'Craft' 22
            @pushlist 'Craft' 9
            @pushlist 'Craft' 0x153b
          elseif @ingump 0x5afbd742 'full apron'
            @pushlist 'Craft' 22
            @pushlist 'Craft' 16
            @pushlist 'Craft' 0x153d
            // Footwear
          elseif @ingump 0x5afbd742 'fur boots'
            @pushlist 'Craft' 29
            @pushlist 'Craft' 9
            @pushlist 'Craft' 0x2307
          else
            break
          endif
        endif
      else
        if not @findalias 'crafting'
          // Leather
          if @ingump 0x5afbd742 'leather gorget'
            @pushlist 'Craft' 36
            @pushlist 'Craft' 23
            @pushlist 'Craft' 0x13c7
          elseif @ingump 0x5afbd742 'leather cap'
            @pushlist 'Craft' 36
            @pushlist 'Craft' 30
            @pushlist 'Craft' 0x1db9
          elseif @ingump 0x5afbd742 'leather gloves'
            @pushlist 'Craft' 36
            @pushlist 'Craft' 37
            @pushlist 'Craft' 0x13c6
          elseif @ingump 0x5afbd742 'leather sleeves'
            @pushlist 'Craft' 36
            @pushlist 'Craft' 44
            @pushlist 'Craft' 0x13cd
          elseif @ingump 0x5afbd742 'leather leggings'
            @pushlist 'Craft' 36
            @pushlist 'Craft' 51
            @pushlist 'Craft' 0x13cb
          elseif @ingump 0x5afbd742 'leather tunic'
            @pushlist 'Craft' 36
            @pushlist 'Craft' 58
            @pushlist 'Craft' 0x13cc
            // Studded
          elseif @ingump 0x5afbd742 'studded gorget'
            @pushlist 'Craft' 43
            @pushlist 'Craft' 2
            @pushlist 'Craft' 0x13d6
          elseif @ingump 0x5afbd742 'studded gloves'
            @pushlist 'Craft' 43
            @pushlist 'Craft' 9
            @pushlist 'Craft' 0x13d5
          elseif @ingump 0x5afbd742 'studded sleeves'
            @pushlist 'Craft' 43
            @pushlist 'Craft' 16
            @pushlist 'Craft' 0x13dc
          elseif @ingump 0x5afbd742 'studded leggings'
            @pushlist 'Craft' 43
            @pushlist 'Craft' 23
            @pushlist 'Craft' 0x13da
          elseif @ingump 0x5afbd742 'studded tunic'
            @pushlist 'Craft' 43
            @pushlist 'Craft' 30
            @pushlist 'Craft' 0x13db
            // Female Armor
          elseif @ingump 0x5afbd742 'leather shorts'
            @pushlist 'Craft' 50
            @pushlist 'Craft' 2
            @pushlist 'Craft' 0x1c00
          elseif @ingump 0x5afbd742 'leather skirt'
            @pushlist 'Craft' 50
            @pushlist 'Craft' 9
            @pushlist 'Craft' 0x1c08
          elseif @ingump 0x5afbd742 'leather bustier'
            @pushlist 'Craft' 50
            @pushlist 'Craft' 16
            @pushlist 'Craft' 0x1c0a
          elseif @ingump 0x5afbd742 'studded bustier'
            @pushlist 'Craft' 50
            @pushlist 'Craft' 23
            @pushlist 'Craft' 0x1c0c
          elseif @ingump 0x5afbd742 'female leather armor'
            @pushlist 'Craft' 50
            @pushlist 'Craft' 30
            @pushlist 'Craft' 0x1c06
          elseif @ingump 0x5afbd742 'studded armor'
            @pushlist 'Craft' 50
            @pushlist 'Craft' 37
            @pushlist 'Craft' 0x1c02
          elseif @ingump 0x5afbd742 'thigh boots'
            @pushlist 'Craft' 29
            @pushlist 'Craft' 51
            @pushlist 'Craft' 0x1711
          elseif @ingump 0x5afbd742 'shoes'
            @pushlist 'Craft' 29
            @pushlist 'Craft' 37
            @pushlist 'Craft' 0x170f
          elseif @ingump 0x5afbd742 'sandals'
            @pushlist 'Craft' 29
            @pushlist 'Craft' 30
            @pushlist 'Craft' 0x170d
          elseif @ingump 0x5afbd742 'boots'
            @pushlist 'Craft' 29
            @pushlist 'Craft' 44
            @pushlist 'Craft' 0x170b
          else
            break
          endif
          // Define resource
          if @ingump 0x5afbd742 'barbed'
            @pushlist 'Craft' 27
            @pushlist 'Craft' 2129
          elseif @ingump 0x5afbd742 'horned'
            @pushlist 'Craft' 20
            @pushlist 'Craft' 2117
          elseif @ingump 0x5afbd742 'spined'
            @pushlist 'Craft' 13
            @pushlist 'Craft' 2220
          else
            @pushlist 'Craft' 6
            @pushlist 'Craft' 0
          endif
        endif
        // Check for leathers
        if @counttype 0x1081 Craft[4] 'backpack' < 50
          while @movetype 0x1081 'backpack' 'Restock'
            pause 1500
          endwhile
          if @movetype 0x1081 'Restock' 'backpack' 0 0 0 Craft[4] 100
            pause 1500
          else
            sysmsg 'Out of leathers!' 25
            @canceltarget
            stop
          endif
        endif
      endif
      // Search for existing items
      while @findtype Craft[2] 'any' 'backpack'
        target! 'found'
        waitfortarget 5000
        if not targetexists 'server' and @injournal 'must be exceptional' 'system'
          // Recycle this item
          if usetype! 0xf9f
            waitfortarget 5000
            target! 'found'
            pause 1500
          endif
          // Unable to recycle, trash item
          if @findobject 'found'
            @moveitem! 'found' 'Trash Barrel'
            pause 1500
          endif
          replygump 0x5afbd742 2
          waitforgump 0x5afbd742 15000
          waitfortarget 5000
          clearjournal
        endif
      endwhile
      // Craft new items if necessary
      if targetexists 'server'
        // Check tool before craft
        if not @findobject 'tool'
          break
        endif
        // Swap resource and category only once per BOD
        if not @findobject 'crafting' 'any' 'backpack'
          @setalias 'crafting' 'bod'
          // Resource
          if list 'Craft' == 5
            replygump 0x38920abd 7
            waitforgump 0x38920abd 5000
            replygump 0x38920abd Craft[3]
            waitforgump 0x38920abd 5000
          endif
          // Category
          replygump 0x38920abd Craft[0]
          waitforgump 0x38920abd 5000
        endif
        replygump 0x38920abd Craft[1]
        waitforgump 0x38920abd 5000
        pause 250
      endif
    endwhile
    // BOD is complete, move to destination
    if not targetexists 'server'
      @moveitem 'bod' 'Bulk Destination'
      // Trash BOD or missing definitions
    elseif not @findalias 'crafting'
      @moveitem 'bod' 'Trash BODs Destination'
    endif
    // Out of tools
  elseif not @movetype 0xf9d 'Restock' 'backpack'
    sysmsg 'Out of sewing kits!' 25
    @canceltarget
    stop
  endif
  pause 1500
elseif not property 'Deeds In Book: 0' 'Bulk Source'
  useobject! 'Bulk Source'
  waitforgump 0x54f555df 15000
  replygump 0x54f555df 5
  pause 1500
else
  sysmsg 'Unable to find BODs to fill.' 64
  @canceltarget
  stop
endif

Blacksmith
Instructions:
- Mark "Loop" and play the macro
- "Bulk Source" is the BOB with BODs you want to fill
- "Bulk Destination" is another BOB where filled BODs will be placed
- "Restock" is a container with ingots (iron, dull copper, agapite, etc) and tongs (or smith hammers)
- "Trash BODs Destination" can be a container or a BOB where the macro will place BODs it cannot fill
- Keep your character close to a trash barrel, an anvil and all selected containers

// Author: Kraz
// Description: Blacksmith BOD Filler
// v2.0: (1) easier to update, read and edit craft info, (2) search, recycle and combine existing items before crafting, (3) faster crafting due to gump category swap improvements, (4) added resource handler
if not @findobject 'Bulk Source'
  promptalias 'Bulk Source'
endif
if not @findobject 'Bulk Destination'
  promptalias 'Bulk Destination'
endif
if not @findobject 'Restock'
  promptalias 'Restock'
endif
if not @findobject 'Trash BODs Destination'
  promptalias 'Trash BODs Destination'
endif
if not @findobject 'Trash Barrel'
  promptalias 'Trash Barrel'
endif
// Craft info placeholder
if not listexists 'Craft'
  @createlist 'Craft'
  // 0: Category, 1: Button, 2: Graphic, 3: Resource Button, 4: Resource Color
endif
// Search for a BOD to fill
if @findtype 0x2258 0x44E 'backpack' and @property 'small' 'found'
  // Reset craft state
  @clearlist 'Craft'
  @unsetalias 'crafting'
  // Define and open new BOD
  @setalias 'bod' 'found'
  useobject! 'bod'
  waitforgump 0x5afbd742 15000
  // Combine items
  if not targetexists 'server'
    replygump 0x5afbd742 2
    waitforgump 0x5afbd742 15000
    waitfortarget 5000
  endif
  // Check for tools
  if @findtype 0xfbb 0 'backpack' or @findtype 0x13e3 0 'backpack'
    pause 1500
    @setalias 'tool' 'found'
    useobject! 'tool'
    waitforgump 0x38920abd 15000
    // Craft
    while targetexists 'server'
      if not @findalias 'crafting'
        // Ringmail
        if @ingump 0x5afbd742 'ringmail gloves'
          @pushlist 'Craft' 1
          @pushlist 'Craft' 2
          @pushlist 'Craft' 0x13eb
        elseif @ingump 0x5afbd742 'ringmail leggings'
          @pushlist 'Craft' 1
          @pushlist 'Craft' 9
          @pushlist 'Craft' 0x13f0
        elseif @ingump 0x5afbd742 'ringmail sleeves'
          @pushlist 'Craft' 1
          @pushlist 'Craft' 16
          @pushlist 'Craft' 0x13ee
        elseif @ingump 0x5afbd742 'ringmail tunic'
          @pushlist 'Craft' 1
          @pushlist 'Craft' 23
          @pushlist 'Craft' 0x13ec
          // Chainmail
        elseif @ingump 0x5afbd742 'chainmail coif'
          @pushlist 'Craft' 8
          @pushlist 'Craft' 2
          @pushlist 'Craft' 0x13bb
        elseif @ingump 0x5afbd742 'chainmail leggings'
          @pushlist 'Craft' 8
          @pushlist 'Craft' 9
          @pushlist 'Craft' 0x13be
        elseif @ingump 0x5afbd742 'chainmail tunic'
          @pushlist 'Craft' 8
          @pushlist 'Craft' 16
          @pushlist 'Craft' 0x13bf
          // Platemail
        elseif @ingump 0x5afbd742 'platemail arms'
          @pushlist 'Craft' 15
          @pushlist 'Craft' 2
          @pushlist 'Craft' 0x1410
        elseif @ingump 0x5afbd742 'platemail gloves'
          @pushlist 'Craft' 15
          @pushlist 'Craft' 9
          @pushlist 'Craft' 0x1414
        elseif @ingump 0x5afbd742 'platemail gorget'
          @pushlist 'Craft' 15
          @pushlist 'Craft' 16
          @pushlist 'Craft' 0x1413
        elseif @ingump 0x5afbd742 'platemail legs'
          @pushlist 'Craft' 15
          @pushlist 'Craft' 23
          @pushlist 'Craft' 0x1411
        elseif @ingump 0x5afbd742 'platemail tunic'
          @pushlist 'Craft' 15
          @pushlist 'Craft' 30
          @pushlist 'Craft' 0x1415
        elseif @ingump 0x5afbd742 'female plate'
          @pushlist 'Craft' 15
          @pushlist 'Craft' 37
          @pushlist 'Craft' 0x1c04
          // Helmets
        elseif @ingump 0x5afbd742 'bascinet'
          @pushlist 'Craft' 22
          @pushlist 'Craft' 2
          @pushlist 'Craft' 0x140c
        elseif @ingump 0x5afbd742 'close helmet'
          @pushlist 'Craft' 22
          @pushlist 'Craft' 9
          @pushlist 'Craft' 0x1408
        elseif @ingump 0x5afbd742 'helmet'
          @pushlist 'Craft' 22
          @pushlist 'Craft' 16
          @pushlist 'Craft' 0x140a
        elseif @ingump 0x5afbd742 'norse helm'
          @pushlist 'Craft' 22
          @pushlist 'Craft' 23
          @pushlist 'Craft' 0x140e
        elseif @ingump 0x5afbd742 'plate helm'
          @pushlist 'Craft' 22
          @pushlist 'Craft' 30
          @pushlist 'Craft' 0x1412
          // Shields
        elseif @ingump 0x5afbd742 'buckler'
          @pushlist 'Craft' 29
          @pushlist 'Craft' 2
          @pushlist 'Craft' 0x1b73
        elseif @ingump 0x5afbd742 'bronze shield'
          @pushlist 'Craft' 29
          @pushlist 'Craft' 9
          @pushlist 'Craft' 0x1b72
        elseif @ingump 0x5afbd742 'heater shield'
          @pushlist 'Craft' 29
          @pushlist 'Craft' 16
          @pushlist 'Craft' 0x1b76
        elseif @ingump 0x5afbd742 'metal shield'
          @pushlist 'Craft' 29
          @pushlist 'Craft' 23
          @pushlist 'Craft' 0x1b7b
        elseif @ingump 0x5afbd742 'metal kite shield'
          @pushlist 'Craft' 29
          @pushlist 'Craft' 30
          @pushlist 'Craft' 0x1b74
        elseif @ingump 0x5afbd742 'tear kite shield'
          @pushlist 'Craft' 29
          @pushlist 'Craft' 37
          @pushlist 'Craft' 0x1b79
          // Bladed
        elseif @ingump 0x5afbd742 'broadsword'
          @pushlist 'Craft' 36
          @pushlist 'Craft' 9
          @pushlist 'Craft' 0xf5e
        elseif @ingump 0x5afbd742 'cutlass'
          @pushlist 'Craft' 36
          @pushlist 'Craft' 23
          @pushlist 'Craft' 0x1441
        elseif @ingump 0x5afbd742 'dagger'
          @pushlist 'Craft' 36
          @pushlist 'Craft' 30
          @pushlist 'Craft' 0xf52
        elseif @ingump 0x5afbd742 'katana'
          @pushlist 'Craft' 36
          @pushlist 'Craft' 37
          @pushlist 'Craft' 0x13ff
        elseif @ingump 0x5afbd742 'kryss'
          @pushlist 'Craft' 36
          @pushlist 'Craft' 44
          @pushlist 'Craft' 0x1401
        elseif @ingump 0x5afbd742 'longsword'
          @pushlist 'Craft' 36
          @pushlist 'Craft' 51
          @pushlist 'Craft' 0xf61
        elseif @ingump 0x5afbd742 'scimitar'
          @pushlist 'Craft' 36
          @pushlist 'Craft' 58
          @pushlist 'Craft' 0x13b6
        elseif @ingump 0x5afbd742 'viking sword'
          @pushlist 'Craft' 36
          @pushlist 'Craft' 65
          @pushlist 'Craft' 0x13b9
          // Axes
        elseif @ingump 0x5afbd742 'large battle axe'
          @pushlist 'Craft' 43
          @pushlist 'Craft' 30
          @pushlist 'Craft' 0x13fb
        elseif @ingump 0x5afbd742 'double axe'
          @pushlist 'Craft' 43
          @pushlist 'Craft' 16
          @pushlist 'Craft' 0xf4b
        elseif @ingump 0x5afbd742 "executioner's axe"
          @pushlist 'Craft' 43
          @pushlist 'Craft' 23
          @pushlist 'Craft' 0xf45
        elseif @ingump 0x5afbd742 'battle axe'
          @pushlist 'Craft' 43
          @pushlist 'Craft' 9
          @pushlist 'Craft' 0xf47
        elseif @ingump 0x5afbd742 'two handed axe'
          @pushlist 'Craft' 43
          @pushlist 'Craft' 37
          @pushlist 'Craft' 0x1443
        elseif @ingump 0x5afbd742 'war axe'
          @pushlist 'Craft' 43
          @pushlist 'Craft' 44
          @pushlist 'Craft' 0x13b0
        elseif @ingump 0x5afbd742 'axe'
          @pushlist 'Craft' 43
          @pushlist 'Craft' 2
          @pushlist 'Craft' 0xf49
          // Polearms
        elseif @ingump 0x5afbd742 'bardiche'
          @pushlist 'Craft' 50
          @pushlist 'Craft' 2
          @pushlist 'Craft' 0xf4d
        elseif @ingump 0x5afbd742 'halberd'
          @pushlist 'Craft' 50
          @pushlist 'Craft' 23
          @pushlist 'Craft' 0x143e
        elseif @ingump 0x5afbd742 'short spear'
          @pushlist 'Craft' 50
          @pushlist 'Craft' 44
          @pushlist 'Craft' 0x1403
        elseif @ingump 0x5afbd742 'spear'
          @pushlist 'Craft' 50
          @pushlist 'Craft' 58
          @pushlist 'Craft' 0xf62
        elseif @ingump 0x5afbd742 'war fork'
          @pushlist 'Craft' 50
          @pushlist 'Craft' 65
          @pushlist 'Craft' 0x1405
          // Bashing
        elseif @ingump 0x5afbd742 'war mace'
          @pushlist 'Craft' 57
          @pushlist 'Craft' 30
          @pushlist 'Craft' 0x1407
        elseif @ingump 0x5afbd742 'hammer pick'
          @pushlist 'Craft' 57
          @pushlist 'Craft' 2
          @pushlist 'Craft' 0x143d
        elseif @ingump 0x5afbd742 'mace'
          @pushlist 'Craft' 57
          @pushlist 'Craft' 9
          @pushlist 'Craft' 0xf5c
        elseif @ingump 0x5afbd742 'maul'
          @pushlist 'Craft' 57
          @pushlist 'Craft' 16
          @pushlist 'Craft' 0x143b
        elseif @ingump 0x5afbd742 'war hammer'
          @pushlist 'Craft' 57
          @pushlist 'Craft' 37
          @pushlist 'Craft' 0x1439
        else
          break
        endif
        // Define resource
        if @ingump 0x5afbd742 'valorite'
          @pushlist 'Craft' 62
          @pushlist 'Craft' 2219
        elseif @ingump 0x5afbd742 'verite'
          @pushlist 'Craft' 55
          @pushlist 'Craft' 2207
        elseif @ingump 0x5afbd742 'agapite'
          @pushlist 'Craft' 48
          @pushlist 'Craft' 2425
        elseif @ingump 0x5afbd742 'gold'
          @pushlist 'Craft' 41
          @pushlist 'Craft' 2213
        elseif @ingump 0x5afbd742 'bronze ingots'
          @pushlist 'Craft' 34
          @pushlist 'Craft' 2418
        elseif @ingump 0x5afbd742 'shadow iron'
          @pushlist 'Craft' 20
          @pushlist 'Craft' 2406
        elseif @ingump 0x5afbd742 'dull copper'
          @pushlist 'Craft' 13
          @pushlist 'Craft' 2419
        elseif @ingump 0x5afbd742 'copper'
          @pushlist 'Craft' 27
          @pushlist 'Craft' 2413
        else
          @pushlist 'Craft' 6
          @pushlist 'Craft' 0
        endif
      endif
      // Check for ingots
      if @counttype 0x1bf2 Craft[4] 'backpack' < 50
        while @movetype 0x1bf2 'backpack' 'Restock'
          pause 1500
        endwhile
        if @movetype 0x1bf2 'Restock' 'backpack' 0 0 0 Craft[4] 100
          pause 1500
        else
          sysmsg 'Out of ingots!' 25
          @canceltarget
          stop
        endif
      endif
      // Search for existing items
      while @findtype Craft[2] Craft[4] 'backpack'
        target! 'found'
        waitfortarget 5000
        if not targetexists 'server' and @injournal 'must be exceptional' 'system'
          // Recycle this item
          replygump 0x38920abd 14
          waitfortarget 5000
          target! 'found'
          pause 1500
          // Unable to recycle, trash item
          if @findobject 'found'
            @moveitem! 'found' 'Trash Barrel'
            pause 1500
          endif
          replygump 0x5afbd742 2
          waitforgump 0x5afbd742 15000
          waitfortarget 5000
          clearjournal
        endif
      endwhile
      // Craft new items if necessary
      if targetexists 'server'
        // Check tool before craft
        if not @findobject 'tool'
          break
        endif
        // Swap resource and category only once per BOD
        if not @findobject 'crafting' 'any' 'backpack'
          @setalias 'crafting' 'bod'
          // Resource
          if list 'Craft' == 5
            replygump 0x38920abd 7
            waitforgump 0x38920abd 5000
            replygump 0x38920abd Craft[3]
            waitforgump 0x38920abd 5000
          endif
          // Category
          replygump 0x38920abd Craft[0]
          waitforgump 0x38920abd 5000
        endif
        replygump 0x38920abd Craft[1]
        waitforgump 0x38920abd 5000
        pause 250
      endif
    endwhile
    // BOD is complete, move to destination
    if not targetexists 'server'
      @moveitem 'bod' 'Bulk Destination'
      // Trash BOD or missing definitions
    elseif not @findalias 'crafting'
      @moveitem 'bod' 'Trash BODs Destination'
    endif
    // Out of tools
  elseif not @movetype 0xfbb 'Restock' 'backpack' and not @movetype 0x13e3 'Restock' 'backpack'
    sysmsg 'Out of tongs and smith hammers!' 25
    @canceltarget
    stop
  endif
  pause 1500
elseif not property 'Deeds In Book: 0' 'Bulk Source'
  useobject! 'Bulk Source'
  waitforgump 0x54f555df 15000
  replygump 0x54f555df 5
  pause 1500
else
  sysmsg 'Unable to find BODs to fill.' 64
  @canceltarget
  stop
endif

 

[darthdeus]

A mining macro that can walk further when there is no more ore would be wonderful.

I've been using this http://www.uoforum.com/threads/mining-macro.68751/ one and it works great, but I have to move my craft every 30 seconds to a new location, and check if there's any ore, and move him further if not. Having this automated would probably also help in efficiency in the sense that I usually skip a few blocks when doing this by hand to save time.